Arduino - Contrôle du bouton de la souris

À l'aide de la bibliothèque de souris, vous pouvez contrôler le curseur à l'écran d'un ordinateur avec un Arduino Leonardo, Micro ou Due.

Cet exemple particulier utilise cinq boutons poussoirs pour déplacer le curseur à l'écran. Quatre des boutons sont directionnels (haut, bas, gauche, droite) et un est pour un clic gauche de la souris. Le mouvement du curseur d'Arduino est toujours relatif. Chaque fois qu'une entrée est lue, la position du curseur est mise à jour par rapport à sa position actuelle.

Chaque fois que l'un des boutons directionnels est enfoncé, Arduino déplacera la souris, mappant une entrée HIGH sur une plage de 5 dans la direction appropriée.

Le cinquième bouton sert à contrôler un clic gauche de la souris. Lorsque le bouton est relâché, l'ordinateur reconnaît l'événement.

Composants requis

Vous aurez besoin des composants suivants -

  • 1 × planche à pain
  • 1 × carte Arduino Leonardo, Micro ou Due
  • Résistance 5 × 10k ohm
  • 5 × boutons poussoirs momentanés

Procédure

Suivez le schéma de circuit et connectez les composants sur la carte d'expérimentation comme indiqué dans l'image ci-dessous.

Esquisser

Ouvrez le logiciel Arduino IDE sur votre ordinateur. Le codage en langage Arduino contrôlera votre circuit. Ouvrez un nouveau fichier d'esquisse en cliquant sur Nouveau.

Pour cet exemple, vous devez utiliser Arduino IDE 1.6.7

Code Arduino

/*
   Button Mouse Control
   For Leonardo and Due boards only .Controls the mouse from 
   five pushbuttons on an Arduino Leonardo, Micro or Due.
   Hardware:
   * 5 pushbuttons attached to D2, D3, D4, D5, D6
   The mouse movement is always relative. This sketch reads
   four pushbuttons, and uses them to set the movement of the mouse.
   WARNING: When you use the Mouse.move() command, the Arduino takes
   over your mouse! Make sure you have control before you use the mouse commands.
*/

#include "Mouse.h"
// set pin numbers for the five buttons:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;
int range = 5; // output range of X or Y movement; affects movement speed
int responseDelay = 10; // response delay of the mouse, in ms

void setup() {
   // initialize the buttons' inputs:
   pinMode(upButton, INPUT);
   pinMode(downButton, INPUT);
   pinMode(leftButton, INPUT);
   pinMode(rightButton, INPUT);
   pinMode(mouseButton, INPUT);
   // initialize mouse control:
   Mouse.begin();
}

void loop() {
   // read the buttons:
   int upState = digitalRead(upButton);
   int downState = digitalRead(downButton);
   int rightState = digitalRead(rightButton);
   int leftState = digitalRead(leftButton);
   int clickState = digitalRead(mouseButton);
   // calculate the movement distance based on the button states:
   int xDistance = (leftState - rightState) * range;
   int yDistance = (upState - downState) * range;
   // if X or Y is non-zero, move:
   if ((xDistance != 0) || (yDistance != 0)) {
      Mouse.move(xDistance, yDistance, 0);
   }

   // if the mouse button is pressed:
   if (clickState == HIGH) {
      // if the mouse is not pressed, press it:
      if (!Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.press(MOUSE_LEFT);
      }
   } else {                           // else the mouse button is not pressed:
      // if the mouse is pressed, release it:
      if (Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.release(MOUSE_LEFT);
      }
   }
   // a delay so the mouse does not move too fast:
   delay(responseDelay);
}

Code à noter

Connectez votre carte à votre ordinateur avec un câble micro-USB. Les boutons sont connectés aux entrées numériques des broches 2 à 6. Assurez-vous d'utiliser des résistances de tirage 10k.