Langue Q - Table

Les tables sont au cœur de kdb +. Une table est une collection de colonnes nommées implémentées en tant que dictionnaire.q tables sont orientés colonnes.

Créer des tableaux

Les tableaux sont créés à l'aide de la syntaxe suivante -

q)trade:([]time:();sym:();price:();size:())

q)trade
time sym price size
-------------------

Dans l'exemple ci-dessus, nous n'avons pas spécifié le type de chaque colonne. Cela sera défini par la première insertion dans la table.

Une autre façon, nous pouvons spécifier le type de colonne lors de l'initialisation -

q)trade:([]time:`time$();sym:`$();price:`float$();size:`int$())

Ou nous pouvons également définir des tables non vides -

q)trade:([]sym:(`a`b);price:(1 2))

q)trade

 sym   price
-------------
  a      1
  b      2

S'il n'y a pas de colonnes entre crochets comme dans les exemples ci-dessus, le tableau est unkeyed.

Créer un keyed table, nous insérons la (les) colonne (s) de la clé entre crochets.

q)trade:([sym:`$()]time:`time$();price:`float$();size:`int$())

q)trade

 sym   | time price size
-----  | ---------------

On peut également définir les types de colonnes en définissant les valeurs comme des listes nulles de différents types -

q)trade:([]time:0#0Nt;sym:0#`;price:0#0n;size:0#0N)

Obtenir des informations sur la table

Créons une table d'échange -

trade: ([]sym:`ibm`msft`apple`samsung;mcap:2000 4000 9000 6000;ex:`nasdaq`nasdaq`DAX`Dow)

q)cols trade                         / column names of a table
`sym`mcap`ex

q)trade.sym                          / Retrieves the value of column sym
`ibm`msft`apple`samsung

q)show meta trade                    / Get the meta data of a table trade.

  c   | t f a
----- | -----
 Sym  | s
 Mcap | j
 ex   | s

Clés primaires et tables à clé

Table à clé

Une table à clés est un dictionnaire qui mappe chaque ligne d'une table de clés uniques à une ligne correspondante dans une table de valeurs. Prenons un exemple -

val:flip `name`id!(`John`Jenny`Jonathan;9 18 27)
                          / a flip dictionary create table val
id:flip (enlist `eid)!enlist 99 198 297
                          / flip dictionary, having single column eid

Créez maintenant une table à clé simple contenant l'eid comme clé,

q)valid: id ! val

q)valid                 / table name valid, having key as eid

  eid |  name      id
------| ---------------
  99  |  John      9
  198 |  Jenny     18
  297 |  Jonathan  27

Clés étrangères

UNE foreign key définit un mappage des lignes de la table dans laquelle il est défini aux lignes de la table avec le correspondant primary key.

Les clés étrangères fournissent referential integrity. En d'autres termes, une tentative d'insertion d'une valeur de clé étrangère qui n'est pas dans la clé primaire échouera.

Considérez les exemples suivants. Dans le premier exemple, nous définirons une clé étrangère explicitement lors de l'initialisation. Dans le deuxième exemple, nous utiliserons la recherche de clé étrangère qui ne suppose aucune relation préalable entre les deux tables.

Example 1 − Define foreign key on initialization

q)sector:([sym:`SAMSUNG`HSBC`JPMC`APPLE]ex:`N`CME`DAQ`N;MC:1000 2000 3000 4000)

q)tab:([]sym:`sector$`HSBC`APPLE`APPLE`APPLE`HSBC`JPMC;price:6?9f)

q)show meta tab

  c    | t f a
------ | ----------
 sym   | s sector
 price | f

q)show select from tab where sym.ex=`N

  sym     price
----------------
 APPLE   4.65382
 APPLE   4.643817
 APPLE   3.659978

Example 2 − no pre-defined relationship between tables

sector: ([symb:`IBM`MSFT`HSBC]ex:`N`CME`N;MC:1000 2000 3000)
tab:([]sym:`IBM`MSFT`MSFT`HSBC`HSBC;price:5?9f)

Pour utiliser la recherche de clé étrangère, nous devons créer une table à saisir dans le secteur.

q)show update mc:(sector([]symb:sym))[`MC] from tab

  sym     price      mc
--------------------------
  IBM   7.065297    1000
  MSFT  4.812387    2000
  MSFT  6.400545    2000
  HSBC  3.704373    3000
  HSBC  4.438651    3000

Notation générale pour une clé étrangère prédéfinie -

sélectionnez ab à partir de c où a est la clé étrangère (sym), b est a

dans la table de clé primaire (ind), c est le

table de clé étrangère (commerce)

Manipulation des tables

Créons une table d'échange et vérifions le résultat d'une expression de table différente -

q)trade:([]sym:5?`ibm`msft`hsbc`samsung;price:5?(303.00*3+1);size:5?(900*5);time:5?(.z.T-365))

q)trade

  sym        price   size   time
-----------------------------------------
 msft      743.8592  3162  02:32:17.036
 msft      641.7307  2917  01:44:56.936
 hsbc      838.2311  1492  00:25:23.210
 samsung   278.3498  1983  00:29:38.945
 ibm       838.6471  4006  07:24:26.842

Jetons maintenant un coup d'œil aux instructions utilisées pour manipuler les tables à l'aide de q Langue.

Sélectionner

La syntaxe pour utiliser un Select la déclaration est la suivante -

select [columns] [by columns] from table [where clause]

Prenons maintenant un exemple pour montrer comment utiliser l'instruction Select -

q)/ select expression example

q)select sym,price,size by time from trade where size > 2000

    time      |  sym    price     size
------------- | -----------------------
 01:44:56.936 |  msft   641.7307  2917
 02:32:17.036 |  msft   743.8592  3162
 07:24:26.842 |  ibm    838.6471  4006

Insérer

La syntaxe pour utiliser un Insert la déclaration est la suivante -

`tablename insert (values)
Insert[`tablename; values]

Prenons maintenant un exemple pour montrer comment utiliser l'instruction Insert -

q)/ Insert expression example

q)`trade insert (`hsbc`apple;302.0 730.40;3020 3012;09:30:17.00409:15:00.000)
5 6

q)trade

   sym    price     size    time
------------------------------------------
  msft    743.8592  3162   02:32:17.036
  msft    641.7307  2917   01:44:56.936
  hsbc    838.2311  1492   00:25:23.210
 samsung  278.3498  1983   00:29:38.945
  ibm     838.6471  4006   07:24:26.842
  hsbc    302       3020   09:30:17.004
  apple   730.4     3012   09:15:00.000

q)/Insert another value

q)insert[`trade;(`samsung;302.0; 3333;10:30:00.000]
']

q)insert[`trade;(`samsung;302.0; 3333;10:30:00.000)]
,7

q)trade

   sym     price   size     time
----------------------------------------
  msft   743.8592  3162  02:32:17.036
  msft   641.7307  2917  01:44:56.936
  hsbc   838.2311  1492  00:25:23.210
 samsung 278.3498  1983  00:29:38.945
  ibm    838.6471  4006  07:24:26.842
  hsbc   302       3020  09:30:17.004
  apple  730.4     3012  09:15:00.000
 samsung 302       3333  10:30:00.000

Effacer

La syntaxe pour utiliser un Delete la déclaration est la suivante -

delete columns from table
delete from table where clause

Prenons maintenant un exemple pour montrer comment utiliser l'instruction Delete -

q)/Delete expression example

q)delete price from trade

   sym   size       time
-------------------------------
  msft   3162   02:32:17.036
  msft   2917   01:44:56.936
  hsbc   1492   00:25:23.210
 samsung 1983   00:29:38.945
  ibm    4006   07:24:26.842
  hsbc   3020   09:30:17.004
  apple  3012   09:15:00.000
 samsung 3333   10:30:00.000

q)delete from trade where price > 3000

   sym     price     size       time
-------------------------------------------
  msft    743.8592   3162    02:32:17.036
  msft    641.7307   2917    01:44:56.936
  hsbc    838.2311   1492    00:25:23.210
 samsung  278.3498   1983    00:29:38.945
  ibm     838.6471   4006    07:24:26.842
  hsbc    302        3020    09:30:17.004
  apple   730.4      3012    09:15:00.000
 samsung  302        3333    10:30:00.000

q)delete from trade where price > 500

  sym     price     size     time
-----------------------------------------
 samsung  278.3498  1983  00:29:38.945
  hsbc    302       3020  09:30:17.004
 samsung  302       3333  10:30:00.000

Mettre à jour

La syntaxe pour utiliser un Update la déclaration est la suivante -

update column: newValue from table where ….

Utilisez la syntaxe suivante pour mettre à jour le format / type de données d'une colonne à l'aide de la fonction cast -

update column:newValue from `table where …

Prenons maintenant un exemple pour montrer comment utiliser Update déclaration -

q)/Update expression example

q)update size:9000 from trade where price > 600

  sym     price      size     time
------------------------------------------
  msft    743.8592   9000   02:32:17.036
  msft    641.7307   9000   01:44:56.936
  hsbc    838.2311   9000   00:25:23.210
 samsung  278.3498   1983   00:29:38.945
  ibm     838.6471   9000   07:24:26.842
  hsbc    302        3020   09:30:17.004
  apple   730.4      9000   09:15:00.000
 samsung  302        3333   10:30:00.000

q)/Update the datatype of a column using the cast function

q)meta trade

   c  |  t f a
----- | --------
  sym |  s
 price|  f
 size |  j
 time |  t

q)update size:`float$size from trade

  sym     price     size      time
------------------------------------------
  msft    743.8592  3162    02:32:17.036
  msft    641.7307  2917    01:44:56.936 
  hsbc    838.2311  1492    00:25:23.210
 samsung  278.3498  1983    00:29:38.945
  ibm     838.6471  4006    07:24:26.842
  hsbc    302       3020    09:30:17.004
  apple   730.4     3012    09:15:00.000
 samsung  302       3333    10:30:00.000

q)/ Above statement will not update the size column datatype permanently

q)meta trade

   c   |  t f a
------ | --------
  sym  |   s
 price |   f
 size  |   j
 time  |   t
 
q)/to make changes in the trade table permanently, we have do

q)update size:`float$size from `trade
`trade

q)meta trade

   c   |  t f a
------ | --------
  sym  |   s
 price |   f
 size  |   f
 time  |   t